Quarantine challenge

clemenza

Retro Addict
Messages
967
Reaction score
1,358
Points
93
Το update τι κάνει; Μήπως σου καθαρίζει την οθόνη;
Όχι, το update την ενημερώνει. Μπορείς να το βάλεις να τρέξει όλο το πρόγραμμα χωρίς να την ενημερώσει και να κάνεις update στο τέλος για να δεις το output. Είναι σα να το τρέχεις σε fast και slow mode, με ενημέρωση της οθόνης ή χωρίς. Δεν κάνει κάτι παραπάνω...
 

clemenza

Retro Addict
Messages
967
Reaction score
1,358
Points
93
Λοιπόν, σε ORIC δεν γίνεται: το κάθε pixel που σχεδιάζεται με κάποιο χρώμα αλλάζει και το χρώμα του προηγούμενου (!) με αποτέλεσμα να καταλήγουμε με μονόχρωμες γραμμές! :(

Σε Commodore 16 και Plus/4 ναι μεν το μετέφερα και τρέχει σωστά, αλλά παρά τα 121 χρώματα και παρά τα όσα αναφέρει στο manual, φαίνεται να μπορεί να απεικονίσει διαφορετικά χρώματα μόνο κάθε 8x8 pixels. Λειτουργεί πάντως, όπως μπορείτε να δείτε...

19487

Και το listing του:

19488
 

lliont

Retro Starter
Messages
75
Reaction score
276
Points
63
19489

Lion Tiny Basic

5 BCOLOR 0
10 CLS
300 E=-1.3
310 FOR Y=0 TO 199
320 D=-2.4
330 FOR X=0 TO 299
340 Z=0; I=0; A=1
350 REM LOOP
360 S=(Z*Z)-(I*I)+D
370 R=(2*I*Z)+E
380 Z=S
390 I=R
400 A=A+1
405 L=Z*Z+I*I
410 IF ((A<16)*(L<4)) GOTO 360
500 FCOLOR A
510 PLOT X,Y,1
520 D=D+0.0215
530 NEXT X
540 E=E+0.013
550 NEXT Y
560 BCOLOR 0
570 K=WAITK
 

dimfil

Retro Mentor
Messages
1,096
Reaction score
1,814
Points
123
Νο luck στην Atari Basic...

Τι τα θέλατε τα γραφικά και τα pixel που αναβοσβήνουν! Δεν βρήκα πουθενά αναφορά ότι είναι εφικτό αυτό μέσω Basic σε κάποιο από τα Atari graphic modes... Δεν παραδίδω τα όπλα, την άλλη εβδομάδα θα το ξαναδώ αρκεί ο πιτσιρικάς να σταματήσει να μου ζητάει Lion King στο Coinops Next όποτε με βλέπει να κάθομαι στο laptop!

ΥΓ. Το πρώτο του Vinc αποδεικνύεται τεράστιος γρίφος
Το δεύτερο καλύτερα να γραφεί από την αρχή!
Του ChrisTOS πρέπει πρώτα να καταλάβω τι κάνουν όλα αυτά τα Calls γιατί δεν έχω ιδέα από τις ιδιαιτερότητες της Locomotive...
 
Last edited:

clemenza

Retro Addict
Messages
967
Reaction score
1,358
Points
93
Του ChrisTOS πρέπει πρώτα να καταλάβω τι κάνουν όλα αυτά τα Calls γιατί δεν έχω ιδέα από τις ιδιαιτερότητες της Locomotive...
Γενικώς προτείνω ό,τι βάζουμε προς μετατροπή να αποφεύγει POKEs και κλήσεις σε ρουτίνες στην ROM του συστήματος (CALL, SYS, RAND USR κλπ.) οι οποίες είναι πολύ συγκεκριμένες σε κάθε μηχάνημα και αν δεν τις γνωρίζει κάποιος πρέπει να αρχίσει να ψάχνεται για να βρει τι κάνουν.

Επίσης ναι, το 2ο πρόγραμμα του Vincent θέλει κανένα μισάωρο για να περαστεί στον CPC και μετά η μετατροπή του... ΟΚ, ας το γράψουμε στον CPC πρώτα και μετά βλέπουμε!
 

ChrisTOS

Retro Enthusiast
Messages
310
Reaction score
489
Points
63
Νο luck στην Atari Basic...

Τι τα θέλατε τα γραφικά και τα pixel που αναβοσβήνουν! Δεν βρήκα πουθενά αναφορά ότι είναι εφικτό αυτό μέσω Basic σε κάποιο από τα Atari graphic modes... Δεν παραδίδω τα όπλα, την άλλη εβδομάδα θα το ξαναδώ αρκεί ο πιτσιρικάς να σταματήσει να μου ζητάει Lion King στο Coinops Next όποτε με βλέπει να κάθομαι στο laptop!

ΥΓ. Το πρώτο του Vinc αποδεικνύεται τεράστιος γρίφος
Το δεύτερο καλύτερα να γραφεί από την αρχή!
Του ChrisTOS πρέπει πρώτα να καταλάβω τι κάνουν όλα αυτά τα Calls γιατί δεν έχω ιδέα από τις ιδιαιτερότητες της Locomotive...
Vsync. Κάνουν vertical sync για το εφέ και μπορούν να απαλειφθούν.
 

sly*m

Retro Addict
Messages
549
Reaction score
1,403
Points
103
Code:
10 MODE 0:e=-1.3:FOR y%=0 TO 199:d=-2.4:FOR x%=0 TO 159:z=0:i=0:a%=0:WHILE a%<15 AND (z*z+i*i)<4:s=(z*z)-(i*i)+d:r=(2*i*z)+e:z=s:i=r:a%=a%+1:WEND:PLOT x%*4,y%*2,a%:d=d+0.0215:NEXT:e=e+0.013:NEXT

Atari Basic (8bit)

Color hirez:
19490
Code:
0 REM *** sly*m's answer to vincent's lame amstrad mbrot - color ***
10 GRAPHICS 7+16:OPEN #1,4,0,"K":E=-1.3:FOR Y=0 TO 95:D=-2:FOR X=0 TO 159:Z=0:I=0:A=0:GOSUB 30:COLOR A:PLOT X,Y
20 D=D+0.0169:NEXT X:E=E+0.027:NEXT Y:POKE 77,0:GET #1,KEY:CLOSE #1:END
30 IF (Z*Z+I*I)>4 THEN RETURN
40 S=(Z*Z)-(I*I)+D:R=(2*I*Z)+E:Z=S:I=R:A=A+1:IF A>15 THEN RETURN
50 GOTO 30

Monochrome hirez:
19491
Code:
0 REM *** sly*m's answer to vincent's lame amstrad mbrot - monochrome ***
10 GRAPHICS 8+16:OPEN #1,4,0,"K":E=-1.3:FOR Y=0 TO 191:D=-2:FOR X=0 TO 319:Z=0:I=0:A=0:GOSUB 30:COLOR A:PLOT X,Y
20 D=D+8.5E-03:NEXT X:E=E+0.0134:NEXT Y:POKE 77,0:GET #1,KEY:CLOSE #1:END
30 IF (Z*Z+I*I)>4 THEN RETURN
40 S=(Z*Z)-(I*I)+D:R=(2*I*Z)+E:Z=S:I=R:A=A+1:IF A>15 THEN RETURN
50 GOTO 30
edit: lame rems
 
Last edited:

dimfil

Retro Mentor
Messages
1,096
Reaction score
1,814
Points
123
Atari Basic (8bit)

Color hirez:
View attachment 19490
Code:
10 GRAPHICS 7+16:OPEN #1,4,0,"K":E=-1.3:FOR Y=0 TO 95:D=-2:FOR X=0 TO 159:Z=0:I=0:A=0:GOSUB 30:COLOR A:PLOT X,Y
20 D=D+0.0169:NEXT X:E=E+0.027:NEXT Y:POKE 77,0:GET #1,KEY:CLOSE #1:END
30 IF (Z*Z+I*I)>4 THEN RETURN
40 S=(Z*Z)-(I*I)+D:R=(2*I*Z)+E:Z=S:I=R:A=A+1:IF A>15 THEN RETURN
50 GOTO 30

Monochrome hirez:
View attachment 19491
Code:
10 GRAPHICS 8+16:OPEN #1,4,0,"K":E=-1.3:FOR Y=0 TO 191:D=-2:FOR X=0 TO 319:Z=0:I=0:A=0:GOSUB 30:COLOR A:PLOT X,Y
20 D=D+8.5E-03:NEXT X:E=E+0.0134:NEXT Y:POKE 77,0:GET #1,KEY:CLOSE #1:END
30 IF (Z*Z+I*I)>4 THEN RETURN
40 S=(Z*Z)-(I*I)+D:R=(2*I*Z)+E:Z=S:I=R:A=A+1:IF A>15 THEN RETURN
50 GOTO 30
Άρχοντας!
Μου έλυσες τις απορίες μέσα σε ένα post!
 

dimfil

Retro Mentor
Messages
1,096
Reaction score
1,814
Points
123
Τρέχτα σε κανέναν altirra σε warp, γιατί στο real thing θα τελειώσουν μετά την άρση της καραντίνας, δλδ μήνες μετά..!

Εντάξει, και στον Amstrad (winape) δεν το λες και "σφαίρα".. !!!
 

clemenza

Retro Addict
Messages
967
Reaction score
1,358
Points
93
Ερώτηση: έχετε δει το νέο βιντεάκι του 8bit show and tell;


Ενδιαφέρεστε να μετατρέψουμε αυτό το απλό παιχνιδάκι; Το listing του είναι αυτό:

19493

(Η inversed καρδούλα είναι το CLS!)
 

Vincent

Retro Addict
Messages
817
Reaction score
1,635
Points
103
Υπάρχει ένα text benchmark με λαβύρινθο που παίζει σε όλα.
Ο CPC είναι αργός στη basic για να τυπώνει κείμενο.
 

sly*m

Retro Addict
Messages
549
Reaction score
1,403
Points
103
Μέχρι να δω τα άλλα ας βάλω και γω ένα listing από το Α8.

Είναι το Nim, το παιχνίδι με τα σπίρτα, από το 'Games Ataris Play'.

19494

19495

Code:
1000 REM ****************************
1010 REM *                          *
1020 REM *           NIM            *
1030 REM *                          *
1040 REM ****************************
1050 REM
1060 DIM A$(2)
1070 GRAPHICS 0
1080 POSITION 14,3
1090 PRINT "*** NIM ***"
1100 PRINT
1110 PRINT
1120 PRINT "THIS IS THE GAME OF NIM. TO PLAY"
1130 PRINT "YOU ENTER THE NUMBER OF MATCHES TO"
1140 PRINT "REMOVE. THE COMPUTER WILL THEN MAKE"
1150 PRINT "IT'S MOVE. THE ONE WHO TAKES THE"
1160 PRINT "LAST MATCH LOSES."
1170 POSITION 2,23
1180 PRINT "PRESS 'RETURN' TO CONTINUE.";
1190 INPUT A$
1200 PRINT "}"
1210 POSITION 14,3
1220 PRINT "*** NIM ***"
1230 PRINT :PRINT
1240 ? "HOW MANY MATCHES? (4 TO 26)"
1250 INPUT A$:IF A$="" THEN A$="0"
1260 M=VAL(A$)
1270 IF M<4 OR M>26 THEN 1250
1280 GRAPHICS 5
1290 L=0
1300 N=M
1310 W=M
1320 SETCOLOR 0,3,6
1330 SETCOLOR 1,1,10
1340 FOR I=1 TO M
1350 COLOR 2
1360 PLOT 3*I,5
1370 DRAWTO 3*I,15
1380 COLOR 1
1390 PLOT 3*I,4
1400 NEXT I
1410 ? "DO YOU WANT TO MOVE FIRST?"
1420 INPUT A$
1430 IF A$(1,1)="N" THEN 1540
1440 ? "THERE ARE NOW ";M;" MATCH(ES)."
1450 ? "TAKE 1 TO 3 MATCHES ";
1460 INPUT A$:IF A$="" THEN A$="0"
1470 H=VAL(A$)
1480 IF H>3 OR H<1 OR H>M THEN PRINT "BAD NUMBER. TRY AGAIN.":GOTO 1440
1490 X=L+H
1500 GOSUB 1770
1510 L=X
1520 M=M-H
1530 IF M=0 THEN 1690
1540 REM
1550 IF M=1 THEN 1750
1560 R=M-4*INT(M/4)
1570 IF R<>1 THEN 1600
1580 C=INT(3*RND(1))+1
1590 GOTO 1610
1600 C=(R+3)-4*INT((R+3)/4)
1610 X=L+C
1620 ? "MY TURN, I'M THINKING"
1630 GOSUB 1770
1640 L=X
1650 M=M-C:IF M=0 THEN 1750
1660 GOSUB 1770
1670 ? "I TOOK ";C;" MATCH(ES)"
1680 GOTO 1440
1690 REM
1700 ? "I WON! BETTER LUCK NEXT TIME"
1710 ? "DO YOU WANT TO TRY AGAIN"
1720 INPUT A$
1730 IF A$(1,1)<>"N" THEN 1240
1740 PRINT "THANKS FOR THE GAME":END
1750 ? "YOU WON!!! NICE GOING":GOTO 1710
1760 ?
1770 REM
1780 COLOR 0
1790 FOR I=L TO X
1800 FOR J=1 TO 12
1810 PLOT 3*I,3+J
1820 NEXT J
1830 FOR K=1 TO 10
1840 NEXT K
1850 NEXT I
1860 RETURN
tips:

1070 GRAPHICS 0 text mode

1200 PRINT "}" text mode clear screen (για το Atari είναι esc+ctrl+clear)

1280 GRAPHICS 5 mix mode, γραφικά low rez και κάτω παραθυράκι text-input

1320 SETCOLOR 0,3,6
1380 COLOR 1 χρώμα για το κεφάλι του σπίρτου

1330 SETCOLOR 1,1,10
1350 COLOR 2 χρώμα για το ξυλάκι

1780 COLOR 0 σβήνει το σπίρτο
 
Last edited:

dimfil

Retro Mentor
Messages
1,096
Reaction score
1,814
Points
123
Μέχρι να δω τα άλλα ας βάλω και γω ένα listing από το Α8.

Είναι το Nim, το παιχνίδι με τα σπίρτα, από το 'Games Ataris Play'.

View attachment 19494

View attachment 19495

Code:
1000 REM ****************************
1010 REM * *
1020 REM * NIM *
1030 REM * *
1040 REM ****************************
1050 REM
1060 DIM A$(2)
1070 GRAPHICS 0
1080 POSITION 14,3
1090 PRINT "*** NIM ***"
1100 PRINT
1110 PRINT
1120 PRINT "THIS IS THE GAME OF NIM. TO PLAY"
1130 PRINT "YOU ENTER THE NUMBER OF MATCHES TO"
1140 PRINT "REMOVE. THE COMPUTER WILL THEN MAKE"
1150 PRINT "IT'S MOVE. THE ONE WHO TAKES THE"
1160 PRINT "LAST MATCH LOSES."
1170 POSITION 2,23
1180 PRINT "PRESS 'RETURN' TO CONTINUE.";
1190 INPUT A$
1200 PRINT "}"
1210 POSITION 14,3
1220 PRINT "*** NIM ***"
1230 PRINT :PRINT
1240 ? "HOW MANY MATCHES? (4 TO 26)"
1250 INPUT A$:IF A$="" THEN A$="0"
1260 M=VAL(A$)
1270 IF M26 THEN 1250
1280 GRAPHICS 5
1290 L=0
1300 N=M
1310 W=M
1320 SETCOLOR 0,3,6
1330 SETCOLOR 1,1,10
1340 FOR I=1 TO M
1350 COLOR 2
1360 PLOT 3*I,5
1370 DRAWTO 3*I,15
1380 COLOR 1
1390 PLOT 3*I,4
1400 NEXT I
1410 ? "DO YOU WANT TO MOVE FIRST?"
1420 INPUT A$
1430 IF A$(1,1)="N" THEN 1540
1440 ? "THERE ARE NOW ";M;" MATCH(ES)."
1450 ? "TAKE 1 TO 3 MATCHES ";
1460 INPUT A$:IF A$="" THEN A$="0"
1470 H=VAL(A$)
1480 IF H>3 OR HM THEN PRINT "BAD NUMBER. TRY AGAIN.":GOTO 1440
1490 X=L+H
1500 GOSUB 1770
1510 L=X
1520 M=M-H
1530 IF M=0 THEN 1690
1540 REM
1550 IF M=1 THEN 1750
1560 R=M-4*INT(M/4)
1570 IF R<>1 THEN 1600
1580 C=INT(3*RND(1))+1
1590 GOTO 1610
1600 C=(R+3)-4*INT((R+3)/4)
1610 X=L+C
1620 ? "MY TURN, I'M THINKING"
1630 GOSUB 1770
1640 L=X
1650 M=M-C:IF M=0 THEN 1750
1660 GOSUB 1770
1670 ? "I TOOK ";C;" MATCH(ES)"
1680 GOTO 1440
1690 REM
1700 ? "I WON! BETTER LUCK NEXT TIME"
1710 ? "DO YOU WANT TO TRY AGAIN"
1720 INPUT A$
1730 IF A$(1,1)<>"N" THEN 1240
1740 PRINT "THANKS FOR THE GAME":END
1750 ? "YOU WON!!! NICE GOING":GOTO 1710
1760 ?
1770 REM
1780 COLOR 0
1790 FOR I=L TO X
1800 FOR J=1 TO 12
1810 PLOT 3*I,3+J
1820 NEXT J
1830 FOR K=1 TO 10
1840 NEXT K
1850 NEXT I
1860 RETURN
tips:

1070 GRAPHICS 0 text mode

1200 PRINT "}" text mode clear screen (για το Atari είναι esc+ctrl+clear)

1280 GRAPHICS 5 mix mode, γραφικά low rez και κάτω παραθυράκι text-input

1320 SETCOLOR 0,3,6
1380 COLOR 1 χρώμα για το κεφάλι του σπίρτου

1330 SETCOLOR 1,1,10
1350 COLOR 2 χρώμα για το ξυλάκι

1780 COLOR 0 σβήνει το σπίρτο
Αυτή είναι η σωστότερη προσέγγιση.
Μια μικρή επεξήγηση για να μην ψάχνονται όλοι τι κάνει το ένα και το άλλο.
Εγώ θα πρότεινα ακόμη παραπέρα, δυο τρεις λέξεις για το τι κάνει κάθε υπορουτίνα σε κάθε listing ώστε αν δεν μπορεί να μεταφερθεί εύκολα τουλάχιστον να φτιαχτεί κάτι αντίστοιχο από όποιον ενδιαφέρεται.
 

sly*m

Retro Addict
Messages
549
Reaction score
1,403
Points
103
Ερώτηση: έχετε δει το νέο βιντεάκι του 8bit show and tell;


Ενδιαφέρεστε να μετατρέψουμε αυτό το απλό παιχνιδάκι; Το listing του είναι αυτό:

View attachment 19493

(Η inversed καρδούλα είναι το CLS!)
Atari Basic (8bit)

Το port είναι σχετικά straight forward καθώς τα μηχανήματα μοιάζουν. Φυσικά πρέπει να δει κανείς το video για να καταλάβει ακριβώς τι κάνει ο 8-Bit Show And Tell.

Τα slashes ( / \ ) είναι οι ATASCII χαρακτήρες 6 και 7 (δείτε και εδώ)

Στην Atari Basic τα strings πρέπει να δηλωθούν (γραμμή 5). Ο διάδρομος φτιάχνεται από substring του string SP$.

Το POKE 82,0 βάζει το αριστερό περιθώριο στο 0 (ο default text editor έχει περιθώριο 2).

Σε όλα τα RND(seed) το seed είναι η διεύθυνση 53770 (o τυχαίος counter του POKEY). Αυτό εξασφαλίζει ότι η ψευτοτυχαία ακολουθία δεν θα είναι ίδια.

Ανοίγω τον handler του πληκτρολογίου με OPEN #1,4,0,"K", απλά για να πάρω πλήκτρο όταν γίνει CRASH!, στην γραμμή 210. Με το space ξεκινάει καινούριο παιχνίδι, ό,τι άλλο τερματίζει το πρόγραμμα.

GRAPHICS 0 : POKE 752,1 ανοίγω καινούρια text οθόνη και κάνω αόρατο τον κέρσορα.

Καθώς η Atari Basic δεν έχει MID$ string αλλά STRING$(start,end), η MID$ γίνεται με STRING$(start, start+μήκος), γραμμή 50.

Το LOCATE διαβάζει αν έχουμε space στην θέση του παίκτη (του αστερίσκου). Αν όχι χτυπήσαμε τοίχο.

Επειδή δεν θέλω να φτιάξω keyboard manager σε asm (το GET #1,KEY θα περιμένει πλήκτρο), χρησιμοποιώ το joystick 0 για χειρισμό του παίκτη, γραμμές 75 και 80.

19496 19497

Code:
0 REM 10 PRINT RACE ON ATARI 800
1 REM Based on 8-Bit Show And Tell's
2 REM Commodore PET Game
3 REM youtube.com/watch?v=bCTrdVhjjWo
4 REM *******************************
5 DIM R$(75),M$(1),SP$(15):FOR X=1 TO 15:SP$(X)=" ":NEXT X
6 POKE 82,0:R$="":? "}INIT";:FOR X=1 TO 75:M$=CHR$(INT(5.5+RND(53770)+1)):R$(X)=M$:? M$;:NEXT X
7 OPEN #1,4,0,"K"
10 GRAPHICS 0:POKE 752,1:C=20:R=13:W=15:D=0
20 L=0:FOR Z=0 TO 1 STEP 0:X=RND(53770)*10
30 IF X<4 THEN R=R-1:IF R<1 THEN R=1
40 IF X>5 THEN R=R+1:IF R+W>37 THEN R=37-W
50 RN=RND(53770)*35+1:? R$(RN,RN+R);SP$(1,W);R$(RN,RN+37-R-W)
60 D=D+1:L=L+1:IF L>49 THEN L=0:W=W-1:IF W<3 THEN W=3
70 IF D<25 THEN GOTO 20
75 IF STICK(0)=11 THEN C=C-1
80 IF STICK(0)=7 THEN C=C+1
90 LOCATE C,0,V:IF V<>32 THEN 200
100 POSITION C,0:? "*":POSITION 0,23:NEXT Z
200 POSITION 0,23:? SP$;"CRASH!":IF D>H THEN H=D
205 ? "       SCORE : ";D;"   HIGH : ";H
210 GET #1,KEY:IF KEY=32 THEN GOTO 10
220 CLOSE #1:POKE 752,0:POKE 82,2:END
edit: typo
 
Last edited:

dimfil

Retro Mentor
Messages
1,096
Reaction score
1,814
Points
123
@sly*m Το thread παίρνει ακριβώς την τροπή που ήλπιζα! Σε δύο σου post ήδη έλυσα απορίες και έμαθα πράγματα! Η εξαιρετική ιδέα του @ChrisTOS εξελίσσεται σε "σχολείο", τουλάχιστον για εμένα που εξερευνώ την Atari Basic και την Trubo Basic XL αυτό τον καιρό. Μάνο, κάποια πρόταση για βιβλιογραφία, μιας που βρίσκω άπειρα διαθέσιμα αλλά δυστυχώς είναι αδύνατο να βρω χρόνο να συγκρίνω;

@clemenza Πάνο, αυτό το listing είναι "ταμάμ" για το άρθρο των benchmarks... Αν δεις τη διαφορά ταχύτητας στην εκτέλεση ανάμεσα σε Atari Basic και Turbo Basic XL, αποδεικνύει το βασικό σου συμπέρασμα...
 

clemenza

Retro Addict
Messages
967
Reaction score
1,358
Points
93
@sly*m: καταρχάς, σε πρώτη ευκαιρία θα γράψω το Nim σε κάποιο format - δείχνει εύκολο για να μεταφερθεί οπουδήποτε, είναι εξαιρετική ιδέα και μας εξηγείς και οτιδήποτε πάνω στο οποίο θα μπορούσαμε να έχουμε απορία! Συγγνώμη για την καθυστέρηση, αλλά έχω αναλάβει μια δουλειά τις τελευταίες μέρες που, απλά, μου τρώει όλες τις ώρες! :mad:

Για τη μεταφορά σου στο listing του 8bit Show and Tell θα σου πω απλά "ΣΥΓΧΑΡΗΤΗΡΙΑ"! Το έφτιαξες όπως έπρεπε, μας το παρουσίασες εξαιρετικά και, για μία ακόμα φορά έριξες φως σε σημεία που για κάποιους που δεν έχουν εμπειρία από 8bit Ataris ήταν σκοτεινά. Η προσέγγισή σου στο όλο topic είναι υποδειγματική. :thumbup::emoji_heart_eyes:

@dimfil: Δημήτρη, στο συγκεκριμένο προγραμματάκι νομίζω ότι παίζει τεράστιο ρόλο η ταχύτητα απεικόνισης στην οθόνη σε text mode (anyway, σε όσους υπολογιστές έχουν ανεξάρτητα text mode και graphics mode). Σε αυτό το κομμάτι ναι, είναι ιδανικό για benchmark καθώς καλό είναι μία BASIC να είναι ταχύτατη στους υπολογισμούς, αλλά αν σου απεικονίζει 2 χαρακτήρες το δευτερόλεπτο ε, τότε δεν έχει και μεγάλο νόημα, isn't it? o_O
 

dimfil

Retro Mentor
Messages
1,096
Reaction score
1,814
Points
123
Η διαφορά στην ταχύτητα είναι μεγάλη. Στη μια περίπτωση οι χαρακτήρες της "πίστας" εμφανίζονται διακριτά αργά και οι κινήσεις του χαρακτήρα του παίκτη είναι επίσης αργές, ενώ στην άλλη γίνονται όλα ταχύτατα και ομαλότατα. Κριτήριο καθολικής αξιολόγησης ή benchmark δεν είναι, είναι όμως ενδεικτικότατο του πως αντιμετωπίζει η κάθε έκδοση το ίδιο θέμα. Άρα, πιστεύω ότι έχει νόημα...

Edit: να ξεκαθαρίσω ότι στο προηγούμενο post δεν εννοούσα να βάλεις το listing ως benchmark αλλά ότι αυτό το listing δείχνει την αλήθεια του τελικού σου συμπεράσματος που αφορά τους interpreters.
 
Top